Legacy Accelerators or Word 2003 Access Keys

Office 2003 access keys is what Word 2007 calls them, at least that’s what it says in the screentip, or whatever this is called (it still appears when screentips are switched off):

Legacy Key ScreenTip

Before completely discarding the old User Interface (UI), somebody, it seems, took pity on those of us who use the keyboard and devised a mechanism whereby we could continue to use some of the old accelerators. As you’ll probably know if you’ve been using Word 2007 for any length of time, keyboard shortcuts for elements of the new UI behave slightly differently from those for elements of the old UI, but Word 2007 has room for both.

The solution is not complete; some features and facilities no longer exist, for example, and some accelerators don’t work when there is no document open, or when recording a macro, but it is as comprehensive as it can reasonably be and a boon for keyboard users. If, for example, you press Alt+T, O in an English version of Word 2007, you will be presented with the Word Options dialog, the equivalent of the dialog that could be reached from the Menu in earlier versions of Word, by selecting Tools > Options.

The accelerator key mechanism used to be tied to whatever toolbars were on display. Now there are none, so, clearly, something is different. What is different is that it is now tied to a different toolbar, deemed, for the purposes of this facility, to be displayed. The response to pressing an accelerator key combination used to include a display of any intermediate menu. Again, this can no longer be so, and all you get is the screentip shown above indicating the keys you have, so far, pressed. This means you must know the keys you want to press but, if you didn’t, you probably wouldn’t be trying to press them so this isn’t a great hardship.

The toolbar the facility is tied to is a brand new toolbar, the Legacy Keyboard Support toolbar (for some reason that I don’t understand at the moment, its actual name is “&Legacy Keyboard Support”). By default this has six menu options corresponding to six of the options on Word 2003’s menu (Edit, View, Insert, Format, Tools, and Table) and, subordinate to these, the options that used to be on the respective menus.

You will notice that the File menu is not in this list – I don’t know why. Maybe you don’t want that – maybe, for example, you preferred it when you could use Alt+F, I to get to the Document Properties dialog (now somewhat obscured by the UI) rather than the Word Options dialog that it now triggers, when you use the perfectly adequate Alt+T, O for that.

The good news is that the new toolbar is completely customisable, just as toolbars used to be. The only difference is that you don’t get any visual interface to see the results of your efforts (but see Addendum, below). Just as a simple example, here is code to restore the File menu (which does still exist behind the scenes), the Alt+F accelerator, and all subordinate options. This will add the customisation to your Normal Template, which is probably what you will want; you can, however, add it to any Document or Template you choose just by changing the CustomizationContext.

Sub AddFileMenuToLegacySupport()

    CustomizationContext = NormalTemplate ' Default
    
    CommandBars("&Legacy Keyboard Support").Protection = msoBarNoProtection
    AddMenuItem CommandBars("&Legacy Keyboard Support"), _
                CommandBars("Menu Bar").Controls("File")

End Sub
 


Sub AddMenuItem(CBar As CommandBar, CBC As CommandBarControl)

    Dim CBCSub As CommandBarControl
    
    On Error Resume Next
    
    With CBar.Controls.Add(Id:=CBC.Id)
        If .Type = msoControlPopup Then
            For Each CBCSub In CBC.Controls
                AddMenuItem .CommandBar, CBCSub
            Next CBCSub
        End If
    End With

End Sub

There are couple of points deserving of explanation. Firstly, perhaps, the fact that the Legacy Keyboard Support toolbar is protected, so the first thing to do is to remove the protection. Secondly, the code actually copies a Word 2007 version of the File Menu which may not be exactly as the Word 2003 version; despite this, it still contains a placeholder for the MRU file list which, previously, was populated on display and now, is not displayed and, thus, not populated. This placeholder fails to copy and, whilst a more specific solution would be better, this quick sample code simply ignores errors. Lastly, perhaps, you should note that the AddMenuItem procedure is called recursively as often as needed.

If you run the AddFileMenuToLegacySupport procedure, and then press Alt, you will see from the prompts (the correct name escapes me at the moment) that the Office pizza button has been assigned a new key combination. Clever little Word has identified that Alt+F is in use and doesn’t try to reuse it; one little victory for the Luddites! As said, this is just an example - the Word Menu exists, as some kind of virtual entity, and can be tailored just as it always could be; it’s out of sight, it doesn’t have to be out of mind.

Addendum

Since writing this page, Office MVP Bob Buckland has pointed out a slight peculiarity to me. The extra elements that have been added to the Legacy Keyboard Menu sometimes appear on the Add-Ins tab of the Ribbon, in a Group of their own, called Toolbar Commands. This appears to be a minor bug, best ignored in my view.

I may include some more detail in the future (but don’t hold your breath, waiting), but there is, in effect, a switch in Word to display this tab Group (that, I suspect, was used as a testing aid by the developers, but may, I suppose, have been the germ of an idea that never came to fruition) and it should always be off; it is, however, turned on when Word starts and then turned off later by one of several actions, pressing the Alt key until the Key Tips appear being one of the easiest. Once it has been turned off, there is no way for the user to turn it back on, although it is possible that some odd combination of actions may trigger Word, itself, to temporarily turn it back on.

The display of this extra element in the ribbon is really little more than a curiosity, being neither use nor ornament, as my wife would say. It is merely a temporary effect offering nothing of interest, and nothing not otherwise available.